home *** CD-ROM | disk | FTP | other *** search
/ Shareware Overload Trio 2 / Shareware Overload Trio Volume 2 (Chestnut CD-ROM).ISO / dir36 / tsbat46.zip / ARC2ZIP.BAT < prev    next >
DOS Batch File  |  1992-08-30  |  4KB  |  168 lines
  1. echo off
  2. rem
  3. rem Do not distribute ARC2ZIP.BAT separately from the rest of the package
  4. rem
  5.  
  6. rem If you get an "Out of environment space" message, increase your
  7. rem environment space by using shell configuration in config.sys:
  8. rem Example: shell=c:\bin\command.com /e:1024 /p
  9.  
  10. echo.
  11. echo ┌───────────────────────────────────────────────────────────────┐
  12. echo │ Convert and datestamp a single .arc to .zip file with comment │
  13. echo │ By Prof. Timo Salmi, ts@chyde.uwasa.fi, Sun 30-Aug-1992       │
  14. echo └───────────────────────────────────────────────────────────────┘
  15. if not "%1"=="" goto _continue
  16. echo.
  17. echo Usage: ARC2ZIP PackageName [/r(eplace the old .arc with the new .zip)]
  18. echo Use no drive name! No extension!
  19. echo        ┌───────────────┐
  20. echo        │ NO WILDCARDS! │
  21. echo        └───────────────┘
  22. echo.
  23. echo When using for the first time:
  24. echo  1) Make pkunpak.exe and pkzip.exe available
  25. echo  2) Make a new directory e:\arczip\zip for converted files
  26. echo  3) Edit your own zip-file comment to e:\arczip\comment.txt (not provided)
  27. echo  4) Carefully adjust the paths in the batch, if necessary
  28. echo.
  29. echo Usually:
  30. echo  Place the .arc file in directory e:\arczip\arc
  31. echo  And run normally
  32. echo.
  33. echo.
  34. goto _out
  35.  
  36. :_continue
  37. rem Do the necessary programs, the comment file, and zip directory exist
  38. if not exist c:\tools\pkzip.exe goto _err1
  39. if not exist c:\tools\pkunpak.exe goto _err2
  40. if not exist e:\arczip\comment.txt goto _err3
  41. if not exist e:\arczip\zip\nul goto _err8
  42. if not exist c:\tools\scan.exe goto _err11
  43.  
  44. rem Check that wilrcards have not been used
  45. for %%f in (%1) do if "%1"=="%%f" goto :_testext
  46. echo No wildcards allowed in the file name %1
  47. goto _out
  48.  
  49. rem Check that no extension was used
  50. :_testext
  51. set _exten=%1
  52. :_nextchar
  53. set _prev=%_exten%
  54. for %%f in (/%_exten%) do set _exten=%%f
  55. if ".%_exten%"=="%_prev%" goto _extfound
  56. if not "%_exten%"=="%_prev%" goto _nextchar
  57. goto _noext
  58.  
  59. :_extfound
  60. echo No extension allowed in the file name %1
  61. goto _out
  62.  
  63. :_noext
  64. set _exten=
  65. rem Build the names for source .arc and target .zip files
  66. set _filea=e:\arczip\arc\%1.arc
  67. set _filez=e:\arczip\zip\%1.zip
  68. if not exist %_filea% goto _err4
  69. if exist %_filez% goto _err5
  70. if not exist e:\arczip\tmp$$$\nul md e:\arczip\tmp$$$
  71. if exist e:\arczip\tmp$$$\*.* goto _err9
  72.  
  73. rem Test archive integrity
  74. pkunpak -t %_filea%
  75. if errorlevel==1 goto _err10
  76.  
  77. rem Unpack and check for viruses
  78. pkunpak %_filea% e:\arczip\tmp$$$
  79. c:\tools\scan /m /nomem /x e:\arczip\tmp$$$
  80. if errorlevel==1 goto _err12
  81.  
  82. rem Convert, use the date of the latest file, not the current date
  83. pkzip -a %_filez% e:\arczip\comment.txt
  84. pkzip -z %_filez% < e:\arczip\comment.txt
  85. pkzip -d %_filez% comment.txt
  86. pkzip -br:\ -u -m -o %_filez% e:\arczip\tmp$$$\*.*
  87. pkzip -v %_filez%
  88. dir %_filez%
  89. rd e:\arczip\tmp$$$
  90.  
  91. rem State of the /r switch for replacing the old .arc file
  92. if "%2"=="/r" goto _replace
  93. if "%2"=="/R" goto _replace
  94. goto _out
  95.  
  96. rem Replace the old .arc file with the new .zip file
  97. :_replace
  98. echo.
  99. echo To delete %_filea% press any key
  100. echo To cancel, use the Break key now
  101. pause >nul
  102. if not exist %_filez% goto _err6
  103. if exist %_filea% del %_filea%
  104. if exist %_filea% goto _err7
  105. echo.
  106. echo File %_filea% deleted
  107. goto _out
  108.  
  109. :_err1
  110. Echo File c:\tools\pkzip.exe not found
  111. goto _out
  112.  
  113. :_err2
  114. Echo File c:\tools\pkunpak.exe not found
  115. goto _out
  116.  
  117. :_err3
  118. Echo File e:\arczip\comment.txt not found
  119. goto _out
  120.  
  121. :_err4
  122. Echo File %_filea% not found
  123. echo.
  124. echo Usage: ARC2ZIP PackageName [/r(eplace the old .arc with the new .zip)]
  125. echo Use no drive name! No extension!
  126. echo        ┌───────────────┐
  127. echo        │ NO WILDCARDS! │
  128. echo        └───────────────┘
  129. goto _out
  130.  
  131. :_err5
  132. Echo File %_filez% already exists
  133. goto _out
  134.  
  135. :_err6
  136. Echo ARC2ZIP aborted: File %_filez% not found
  137. goto _out
  138.  
  139. :_err7
  140. Echo ARC2ZIP aborted: Disk or file %_filea% is readonly
  141. goto _out
  142.  
  143. :_err8
  144. Echo Error: Directory e:\arczip\zip does not exist
  145. goto _out
  146.  
  147. :_err9
  148. Echo Error: Directory e:\arczip\tmp$$$ is not empty
  149. goto _out
  150.  
  151. :_err10
  152. Echo ARC2ZIP aborted: Error in %_filea%
  153. goto _out
  154.  
  155. :_err11
  156. Echo File c:\box\tools\scan.exe not found
  157. goto _out
  158.  
  159. :_err12
  160. Echo ARC2ZIP aborted: Scan reports problems in c:\arczip\tmp$$$
  161. goto _out
  162.  
  163. :_out
  164. set _filea=
  165. set _filez=
  166. set _exten=
  167. echo on
  168.